#2687 - Include mimeo python module

modules/adblockplus/manifests/web/mimeo.pp

Index: modules/adblockplus/manifests/web/mimeo.pp
===================================================================
new file mode 100644
--- /dev/null
+++ b/modules/adblockplus/manifests/web/mimeo.pp
@@ -0,0 +1,77 @@
+# == Class: adblockplus::web::mimeo
+#
+# Class adblockplus::web::mimeo registers the information received in a
+# http/s petition with an specified format in an specific output.
+#
+# === Parameters:
+#
+# [*format*]
+#   A string containing the desired format for logging.
+#
+#   '$remote_addr - - [$time_local] "$request" $status $bytes_sent "$http_referer"'
+#
+# [*port*]
+#   An integer to setup the port where the script will be listening, defaults
+#   to 8000.
+#
+# [*response*]
+#   A string (like format parameter) representing the response sent to the
+#   client.
+#
+# [*output*]
+#   A string containg the path to the file where the logs will be written.
+#   the special char `-` represents stdout.
+#
+class adblockplus::web::mimeo (
+  $format = '',
+  $port = 8000,
+  $response = '',
+  $output = '-',
+){
+
+  ensure_packages(['python3'])
+
+  file {"/usr/local/bin/mimeo.py":
+    ensure => 'present',
+    owner => 'root',
+    group => 'root',
+    mode => 0755,
+    source => 'puppet:///modules/adblockplus/mimeo.py',
+    require => Package['python3'],
+  }
+
+  file {"/etc/systemd/system/mimeo.service":
+    ensure => 'present',
+    owner => 'root',
+    group => 'root',
+    mode => 0644,
+    content => template('adblockplus/mimeo.service.erb'),
+    require => File['/usr/local/bin/mimeo.py'],
+  }
+
+  Exec{
+    path => ['/usr/bin', '/bin'],
+  }
+
+  exec {"enable-service-mimeo":
+    command => 'systemctl enable mimeo.service',
+    user => 'root',
+    unless => 'systemctl is-enabled mimeo.service',
+    require => File["/etc/systemd/system/mimeo.service"],
+  }
+
+  service {"mimeo":
+    ensure => 'running',
+    hasrestart => false,
+    provider => 'systemd',
+    require => Exec["enable-service-mimeo"],
+  }
+
+  exec {"reload-mimeo-daemon":
+    notify => Service['mimeo'],
+    command => 'systemctl daemon-reload',
+    subscribe => File["/etc/systemd/system/mimeo.service"],
+    refreshonly => true,
+  }
+}
+